c_traceback/CMakeLists.txt at main · c-modules/c_traceback · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
cmake_minimum_required(VERSION 3.14)

project(c_traceback
    VERSION 0.0.1
    LANGUAGES C
    DESCRIPTION "Colorful, lightweight tracebacks in C"
)

### Dependencies & Modules ###
include(GNUInstallDirs)

### Options ###
option(ENABLE_SANITIZERS "Enable address and undefined sanitizers" OFF)
option(BUILD_EXAMPLES "Build example executables" OFF)

### Library ###
add_library(c_traceback STATIC
    src/error.c
    src/error_codes.c
    src/logging.c
    src/trace.c
    src/traceback.c
    src/utils.c
    src/signal_handler.c
)
add_library(c_traceback::c_traceback ALIAS c_traceback)

### Standard (c99) ###
set_target_properties(c_traceback PROPERTIES
    C_STANDARD 99
    C_STANDARD_REQUIRED ON
    POSITION_INDEPENDENT_CODE ON
)

### Includes ###
target_include_directories(c_traceback
    PUBLIC
        $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/include>
        $<INSTALL_INTERFACE:${CMAKE_INSTALL_INCLUDEDIR}>
    PRIVATE
        ${CMAKE_CURRENT_SOURCE_DIR}/src/internal
)

### Warnings ###
if(MSVC)
    target_compile_options(c_traceback PRIVATE /W4)
else()
    target_compile_options(c_traceback PRIVATE
        -Wall -Wextra -Wpedantic -Wshadow -Wpointer-arith
        -Wcast-qual -Wstrict-prototypes -Wmissing-prototypes
    )
endif()

### Sanitizers ###
if(ENABLE_SANITIZERS)
    if(NOT MSVC)
        target_compile_options(c_traceback PRIVATE -fsanitize=address,undefined)
        target_link_options(c_traceback PRIVATE -fsanitize=address,undefined)
    endif()
endif()

### Definitions ###
target_compile_definitions(c_traceback PRIVATE CTB_VERSION="${PROJECT_VERSION}")

### Installation ###
if(PROJECT_IS_TOP_LEVEL)
    include(CMakePackageConfigHelpers)

    install(TARGETS c_traceback
        EXPORT c_tracebackTargets
        ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
        LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
        RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
        INCLUDES DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}
    )

    install(DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}/include/
        DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}
    )

    ### Package config & version ###
    write_basic_package_version_file(
        "${CMAKE_CURRENT_BINARY_DIR}/c_tracebackConfigVersion.cmake"
        VERSION ${PROJECT_VERSION}
        COMPATIBILITY SameMajorVersion
    )

    file(WRITE "${CMAKE_CURRENT_BINARY_DIR}/c_tracebackConfig.cmake.in"
        "@PACKAGE_INIT@\n\n"
        "include(\"\${CMAKE_CURRENT_LIST_DIR}/c_tracebackTargets.cmake\")\n\n"
        "check_required_components(c_traceback)\n"
    )

    configure_package_config_file(
        "${CMAKE_CURRENT_BINARY_DIR}/c_tracebackConfig.cmake.in"
        "${CMAKE_CURRENT_BINARY_DIR}/c_tracebackConfig.cmake"
        INSTALL_DESTINATION "${CMAKE_INSTALL_LIBDIR}/cmake/c_traceback"
    )

    ### Export targets / install cmake files ###
    install(EXPORT c_tracebackTargets
        FILE c_tracebackTargets.cmake
        NAMESPACE c_traceback::
        DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/c_traceback
    )

    install(FILES
        "${CMAKE_CURRENT_BINARY_DIR}/c_tracebackConfig.cmake"
        "${CMAKE_CURRENT_BINARY_DIR}/c_tracebackConfigVersion.cmake"
        DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/c_traceback
    )

    ### Build Examples ###
    if(BUILD_EXAMPLES)
        if(EXISTS "${CMAKE_CURRENT_SOURCE_DIR}/examples/CMakeLists.txt")
            add_subdirectory(examples)
        endif()
    endif()

endif()

### Testing ###
if(EXISTS "${CMAKE_CURRENT_SOURCE_DIR}/tests/CMakeLists.txt")
    enable_testing()
    add_subdirectory(tests)
endif()