biciradar/build.gradle.kts at main · gcaguilar/biciradar · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
import org.jlleitschuh.gradle.ktlint.KtlintExtension

plugins {
  base
  alias(libs.plugins.android.application) apply false
  alias(libs.plugins.android.library) apply false
  alias(libs.plugins.android.kotlin.multiplatform.library) apply false
  alias(libs.plugins.compose.compiler) apply false
  alias(libs.plugins.compose.multiplatform) apply false
  alias(libs.plugins.kotlin.jvm) apply false
  alias(libs.plugins.kotlin.multiplatform) apply false
  alias(libs.plugins.kotlin.serialization) apply false
  alias(libs.plugins.ktlint) apply false
  alias(libs.plugins.metro) apply false
}

allprojects {
  group = "com.gcaguilar.biciradar"
  version = "0.1.0"
}

subprojects {
  apply(plugin = "org.jlleitschuh.gradle.ktlint")

  extensions.configure<KtlintExtension> {
    outputToConsole.set(true)
    ignoreFailures.set(false)
    filter {
      exclude("**/build/**")
      exclude("**/generated/**")
    }
  }
}

val ktlintCheckAll by tasks.registering {
  group = LifecycleBasePlugin.VERIFICATION_GROUP
  description = "Runs ktlint checks for all subprojects."
  dependsOn(subprojects.map { "${it.path}:ktlintCheck" })
}

val ktlintFormatAll by tasks.registering {
  group = "formatting"
  description = "Formats Kotlin sources with ktlint in all subprojects."
  dependsOn(subprojects.map { "${it.path}:ktlintFormat" })
}

tasks.named("check") {
  dependsOn(ktlintCheckAll)
}