build.gradle.kts

import org.jetbrains.changelog.Changelog
import org.jetbrains.changelog.markdownToHTML
import org.jetbrains.intellij.platform.gradle.TestFrameworkType
import org.jetbrains.intellij.platform.gradle.extensions.intellijPlatform
import org.gradle.language.jvm.tasks.ProcessResources

fun properties(key: String) = providers.gradleProperty(key)
fun environment(key: String) = providers.environmentVariable(key)

plugins {
    alias(libs.plugins.kotlin) // Kotlin support
    alias(libs.plugins.gradleIntelliJPlugin) // Gradle IntelliJ Plugin
    alias(libs.plugins.changelog) // Gradle Changelog Plugin
    alias(libs.plugins.qodana) // Gradle Qodana Plugin
    alias(libs.plugins.kover) // Gradle Kover Plugin
}

group = properties("pluginGroup").get()
version = properties("pluginVersion").get()

// Configure project's dependencies
repositories {
    mavenCentral()
    intellijPlatform {
        defaultRepositories()
        snapshots()
    }
}

// Set the JVM language level used to build the project. Java 21 for 2025.2+.
kotlin {
    jvmToolchain {
        languageVersion = JavaLanguageVersion.of(21)
        @Suppress("UnstableApiUsage")
        vendor = JvmVendorSpec.JETBRAINS
    }
    jvmToolchain(21)
}

// Configure Gradle IntelliJ Plugin - read more: https://plugins.jetbrains.com/docs/intellij/tools-gradle-intellij-plugin.html
intellijPlatform {
    pluginConfiguration {
        name = properties("pluginName")
        version = properties("pluginVersion")
        ideaVersion {
            sinceBuild = properties("pluginSinceBuild")
            untilBuild = properties("pluginUntilBuild")
        }
        // Extract the <!-- Plugin description --> section from README.md and provide for the plugin's manifest
        description = providers.fileContents(layout.projectDirectory.file("README.md")).asText.map {
            val start = "<!-- Plugin description -->"
            val end = "<!-- Plugin description end -->"

            with (it.lines()) {
                if (!containsAll(listOf(start, end))) {
                    throw GradleException("Plugin description section not found in README.md:\n$start ... $end")
                }
                subList(indexOf(start) + 1, indexOf(end)).joinToString("\n").let(::markdownToHTML)
            }
        }

        changeNotes = properties("pluginVersion").map { pluginVersion ->
            with(project.changelog) {
                renderItem(
                        (getOrNull(pluginVersion) ?: getUnreleased())
                                .withHeader(false)
                                .withEmptySections(false),
                        Changelog.OutputType.HTML,
                )
            }
        }
    }
    pluginVerification {
        ides {
            recommended()
        }
    }

    signing {
        certificateChain = environment("CERTIFICATE_CHAIN")
        privateKey = environment("PRIVATE_KEY")
        password = environment("PRIVATE_KEY_PASSWORD")
    }

    publishing {
        token = environment("PUBLISH_TOKEN")
        // The pluginVersion is based on the SemVer (https://semver.org) and supports pre-release labels, like 2.1.7-alpha.3
        // Specify pre-release label to publish the plugin in a custom Release Channel automatically. Read more:
        // https://plugins.jetbrains.com/docs/intellij/deployment.html#specifying-a-release-channel
    }
    changelog {
        groups.empty()
        repositoryUrl = properties("pluginRepositoryUrl")
    }
    instrumentCode = true

}
// Configure Gradle Qodana Plugin - read more: https://github.com/JetBrains/gradle-qodana-plugin
qodana {
    cachePath = provider { file(".qodana").canonicalPath }
    reportPath = provider { file("build/reports/inspections").canonicalPath }
    saveReport = true
    showReport = environment("QODANA_SHOW_REPORT").map { it.toBoolean() }.getOrElse(false)
}

// Configure Gradle Kover Plugin - read more: https://github.com/Kotlin/kotlinx-kover#configuration
kover {
    reports {
        total {
            xml {
                onCheck = true
            }
        }
    }
}


tasks {
    wrapper {
        gradleVersion = properties("gradleVersion").get()
    }
    // buildSearchableOptions launches a headless IDE instance and fails if another PyCharm instance
    // is running with the same config/system dirs. Plugins don't require searchable options, so
    // disable by default and allow opt-in via -PbuildSearchableOptionsEnabled=true.
    val buildSearchableOptionsEnabled =
        providers.gradleProperty("buildSearchableOptionsEnabled").map(String::toBoolean).orElse(false)
    named("buildSearchableOptions") {
        enabled = buildSearchableOptionsEnabled.get()
    }
    named<ProcessResources>("processResources") {
        exclude("META-INF/python-common.xml")
        from("resources/META-INF/python-common.xml") {
            rename { "py-core.xml" }
            into("META-INF")
        }
        from("resources/META-INF/python-common.xml") {
            rename { "py-pro.xml" }
            into("META-INF")
        }
    }
    // Workaround for IntelliJ Platform 2025.3 lib/modules issue
    test {
        doFirst {
            // Find the Python plugin helpers directory dynamically
            val pythonPluginDir = project.configurations
                .named("intellijPlatformDependency")
                .get()
                .resolvedConfiguration
                .resolvedArtifacts
                .flatMap { artifact ->
                    val file = artifact.file
                    if (file.isDirectory) {
                        file.walkTopDown()
                            .filter { it.name == "python-ce" && it.isDirectory }
                            .toList()
                    } else {
                        emptyList()
                    }
                }
                .firstOrNull()

            pythonPluginDir?.let {
                val helpersPath = it.resolve("helpers")
                if (helpersPath.exists()) {
                    systemProperty("idea.python.helpers.path", helpersPath.absolutePath)
                    logger.lifecycle("Set idea.python.helpers.path to: ${helpersPath.absolutePath}")
                }
            }
        }
    }
}
dependencies {
    compileOnly("org.apache.tuweni:tuweni-toml:2.3.1")
    compileOnly(group = "org.ini4j", name = "ini4j", version = "0.5.4")
    testImplementation(kotlin("test"))
    testImplementation(libs.junit)
    testImplementation(libs.opentest4j)
    intellijPlatform {
        val type = properties("platformType")
        val version = properties("platformVersion")
        val bundledPlugins = properties("platformBundledPlugins").map { it.split(',').map(String::trim).filter(String::isNotEmpty) }
        val bundledPyCharmPlugin = when (type.get()) {
            "PY" -> "Pythonid"
            else -> "PythonCore"
        }
        // Use pycharm() for PyCharm 2025.3+ (unified distribution)
        pycharm(version)
        bundledPlugins(
            bundledPlugins.get().map { it.trim() } + listOf(bundledPyCharmPlugin)
        )
        testFramework(TestFrameworkType.Platform)
        pluginVerifier()
        zipSigner()
    }
    // implementation(kotlin("stdlib-jdk8")) // Removed to avoid conflicts with IntelliJ's bundled Kotlin
}

sourceSets {
    main {
        java.srcDir("src")
        resources.srcDir("resources")
    }
    test {
        java.srcDir("testSrc")
        resources.srcDir("testData")
    }
}