feat: patch upstream PR - make parsePackagesFromUsePackage consider :pin

nix-community#501

Thanks, @yunhao94

Author: zekedou

README.org

@@ -138,6 +138,14 @@ For example, =emacsWithPackagesFromUsePackage= adds packages which are required
       # `use-package-always-ensure` to `t` in your config.
       alwaysEnsure = true;
 
+      # By default emacsWithPackagesFromUsePackage will prefer to pull in
+      # packages from MELPA.
+      # Setting `alwaysPin` to `gnu` emulates `use-package-always-pin`
+      # and pulls in all use-package references from GNU ELPA.
+      # Note that this is NOT recommended unless you've actually set
+      # `use-package-always-pin` to `"gnu"` in your config.
+      alwaysPin = "gnu";
+
       # For Org mode babel files, by default only code blocks with
       # `:tangle yes` are considered. Setting `alwaysTangle` to `true`
       # will include all code blocks missing the `:tangle` argument,

elisp.nix

@@ -14,6 +14,8 @@ in
   defaultInitFile ? false,
   # emulate `use-package-always-ensure` behavior (defaulting to false)
   alwaysEnsure ? false,
+  # emulate `use-package-always-pin` behavior (defaulting to false)
+  alwaysPin ? false,
   # emulate `#+PROPERTY: header-args:emacs-lisp :tangle yes`
   alwaysTangle ? false,
   extraEmacsPackages ? epkgs: [ ],
@@ -47,6 +49,7 @@ let
       isOrgModeFile
       alwaysTangle
       alwaysEnsure
+      alwaysPin
       ;
   };
   emacsPackages = (pkgs.emacsPackagesFor package).overrideScope (
@@ -61,7 +64,22 @@ in
 emacsWithPackages (
   epkgs:
   let
-    usePkgs = map (name: epkgs.${name} or (mkPackageError name)) packages;
+    pkgArchives = {
+      "gnu" = "elpaPackages";
+      "gnu-devel" = "elpaDevelPackages";
+      "nongnu" = "nongnuPackages";
+      "nongnu-devel" = "nongnuDevelPackages";
+      "melpa" = "melpaPackages";
+      "melpa-stable" = "melpaStablePackages";
+    };
+    usePkgs = map (
+      pkg:
+      if pkg.archive != null then
+        epkgs.${pkgArchives.${pkg.archive}}.${pkg.name}
+          or (mkPackageError "${pkgArchives.${pkg.archive}}.${pkg.name}")
+      else
+        epkgs.${pkg.name} or (mkPackageError pkg.name)
+    ) packages;
     extraPkgs = extraEmacsPackages epkgs;
     defaultInitFilePkg =
       if !((builtins.isBool defaultInitFile) || (lib.isDerivation defaultInitFile)) then

parse.nix

@@ -68,14 +68,23 @@ let
   #   (use-package paredit-mode
   #     :ensure paredit
   #     :hook (emacs-lisp-mode lisp-mode lisp-interaction-mode))
+  #
+  #   (use-package evil
+  #     :ensure t
+  #     :pin nongnu)
   # ''
-  # => [ "direnv" "paredit" ]
+  # => [
+  #      { name = "direnv"; archive = null }
+  #      { name = "paredit"; archive = null }
+  #      { name = "evil"; archive = "nongnu" }
+  #    ]
   parsePackagesFromUsePackage =
     {
       configText,
-      alwaysEnsure ? false,
       isOrgModeFile ? false,
       alwaysTangle ? false,
+      alwaysEnsure ? false,
+      alwaysPin ? false,
     }:
     let
       readFunction =
@@ -133,6 +142,26 @@ let
         else
           [ ];
 
+      getArchive =
+        item:
+        let
+          pinValue = getKeywordValue ":pin" item;
+          packageArchives = [
+            "gnu"
+            "gnu-devel"
+            "nongnu"
+            "nongnu-devel"
+            "melpa"
+            "melpa-stable"
+          ];
+        in
+        if builtins.elem pinValue packageArchives then
+          pinValue
+        else if builtins.elem alwaysPin packageArchives then
+          alwaysPin
+        else
+          null;
+
       recurse =
         item:
         if builtins.isList item && item != [ ] then
@@ -142,8 +171,14 @@ let
           if builtins.elem packageManager [ "use-package" ] then
             if !(isDisabled item) then
               [
-                packageManager
-                (getName item)
+                {
+                  name = packageManager;
+                  archive = null;
+                }
+                {
+                  name = (getName item);
+                  archive = (getArchive item);
+                }
               ]
               ++ map recurse item
             else