flake-review/flake.nix at main · ojsef39/flake-review · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
{
  description = "Review tool for Nix flake pull requests";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
    flake-utils.url = "github:numtide/flake-utils";
  };

  outputs = {
    self,
    nixpkgs,
    flake-utils,
  }:
    flake-utils.lib.eachDefaultSystem (
      system: let
        pkgs = nixpkgs.legacyPackages.${system};
        python = pkgs.python313;
        devPython = python.withPackages (
          ps:
            with ps; [
              setuptools
              wheel
              attrs
              pytest
              pytest-cov
              mypy
              black
              ruff
            ]
        );

        mkDevScript = name: exec:
          pkgs.writeShellApplication {
            inherit name;
            runtimeInputs = [devPython];
            text = exec;
          };

        dTest = mkDevScript "d-test" ''pytest "$@"'';
        dTestCov = mkDevScript "d-test-cov" ''pytest --cov=flake_review --cov-report=term-missing --cov-report=html "$@"'';
        dLint = mkDevScript "d-lint" ''ruff check . "$@"'';
        dFormat = mkDevScript "d-format" ''black . "$@"'';
        dTypecheck = mkDevScript "d-typecheck" ''mypy flake_review "$@"'';

        flakeReview = python.pkgs.buildPythonApplication {
          pname = "flake-review";
          version = "0.1.1";

          src = pkgs.lib.sources.sourceFilesBySuffices ./. [
            ".py"
            ".toml"
            ".txt"
            ".md"
          ];

          format = "pyproject";

          nativeBuildInputs = with python.pkgs; [
            setuptools
            wheel
          ];

          propagatedBuildInputs = with python.pkgs; [
            attrs
          ];

          preFixup = ''
            makeWrapperArgs+=(--prefix PATH : ${
              pkgs.lib.makeBinPath [
                pkgs.nix-diff
                pkgs.git
              ]
            })
          '';

          checkInputs = with python.pkgs; [
            pytest
            pytestCheckHook
          ];

          pythonImportsCheck = ["flake_review"];

          meta = with pkgs.lib; {
            description = "Review tool for Nix flake pull requests";
            homepage = "https://github.com/ojsef39/flake-review";
            license = licenses.mit;
            maintainers = [];
          };
        };
      in {
        packages = {
          default = flakeReview;
          flake-review = flakeReview;
          d-test = dTest;
          d-test-cov = dTestCov;
          d-lint = dLint;
          d-format = dFormat;
          d-typecheck = dTypecheck;
        };

        devShells.default = pkgs.mkShell {
          packages = [
            devPython
            pkgs.nix-diff
            pkgs.git
            dTest
            dTestCov
            dLint
            dFormat
            dTypecheck
          ];

          shellHook = ''
            echo "flake-review development environment"
            echo " - $(python --version)"
          '';
        };

        apps = {
          default = {
            type = "app";
            program = "${flakeReview}/bin/flake-review";
          };
          d-test = {
            type = "app";
            program = "${dTest}/bin/d-test";
          };
          d-test-cov = {
            type = "app";
            program = "${dTestCov}/bin/d-test-cov";
          };
          d-lint = {
            type = "app";
            program = "${dLint}/bin/d-lint";
          };
          d-format = {
            type = "app";
            program = "${dFormat}/bin/d-format";
          };
          d-typecheck = {
            type = "app";
            program = "${dTypecheck}/bin/d-typecheck";
          };
        };
      }
    );
}