terranix-github-configuration/flake.nix at main · terranix/terranix-github-configuration · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
{
  description = "terranix github account configuration";

  inputs = {
    devshell.url = "github:numtide/devshell";
    flake-parts.url = "github:hercules-ci/flake-parts";
    module-github.url = "github:terranix/terranix-module-github";
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
    terranix.inputs.nixpkgs.follows = "nixpkgs";
    terranix.url = "github:terranix/terranix/develop";
    treefmt-nix.inputs.nixpkgs.follows = "nixpkgs";
    treefmt-nix.url = "github:numtide/treefmt-nix";
  };

  outputs =
    inputs@{ flake-parts, ... }:
    flake-parts.lib.mkFlake { inherit inputs; } {
      imports = [
        ./nix/formatter.nix
        ./nix/devshells.nix
      ];
      systems = [ "x86_64-linux" ];
      perSystem =
        {
          config,
          self',
          inputs',
          pkgs,
          system,
          ...
        }:
        let
          opentofu = "${pkgs.opentofu}/bin/tofu";
          terranixConfiguration = inputs.terranix.lib.terranixConfiguration {
            inherit system;
            modules = [
              inputs.module-github.terranixModule
              ./config.nix
            ];
          };
        in
        {

          apps.default = self'.apps.apply;

          # nix run ".#apply"
          apps.apply = {
            type = "app";
            program = toString (
              pkgs.writers.writeBash "apply" ''
                if [[ -e config.tf.json ]]; then rm -f config.tf.json; fi
                cp ${terranixConfiguration} config.tf.json \
                  && ${opentofu} init \
                  && ${opentofu} apply
              ''
            );
          };

          # nix run ".#destroy"
          apps.destroy = {
            type = "app";
            program = toString (
              pkgs.writers.writeBash "destroy" ''
                if [[ -e config.tf.json ]]; then rm -f config.tf.json; fi
                cp ${terranixConfiguration} config.tf.json \
                  && ${opentofu} init \
                  && ${opentofu} destroy
              ''
            );
          };

        };
    };
}