libyaul-gdbstub/gdbstub.x at master · yaul-org/libyaul-gdbstub · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
/*
 * Copyright (c) 2012-2019
 * See LICENSE for details.
 *
 * Joe Fenton <jlfenton65@gmail.com>
 * Israel Jacquez <mrkotfw@gmail.com>
 */

OUTPUT_FORMAT ("elf32-sh")
OUTPUT_ARCH (sh)
ENTRY (_start)
SEARCH_DIR ("$YAUL_INSTALL_ROOT/$YAUL_ARCH_SH_PREFIX/lib");

MEMORY {
  ram (Wx) : ORIGIN = 0x202FE000, LENGTH = 0x00002000
}

SECTIONS
{
  .header ORIGIN(ram) :
  {
     LONG(0x00010000); /* Version: BCD: Major, minor, patch */
     LONG(_gdb_init);
     LONG(_gdb_device);

     . = ALIGN(16);
  }

  .text . :
  {
     PROVIDE_HIDDEN (__text_start = .);

     KEEP (*(.text.start)) /* Keep _start at the start */
     KEEP (*(.text.*))
     KEEP (*(.text))
     KEEP (*(.gnu.linkonce.t.*))

     PROVIDE_HIDDEN (__text_end = .);
  }

  .rodata . :
  {
     . = ALIGN (0x10);

     *(.rdata)
     *(.rodata)
     *(.rodata.*)
     *(.gnu.linkonce.r.*)
  }

  .data . :
  {
     . = ALIGN (0x10);

     PROVIDE_HIDDEN (__data_start = .);

     *(.data)
     *(.data.*)
     *(.gnu.linkonce.d.*)
     *(.sdata)
     *(.sdata.*)
     *(.gnu.linkonce.s.*)

     PROVIDE_HIDDEN (__data_end = .);
  }

  .bss . :
  {
     . = ALIGN (0x10);

     PROVIDE (__bss_start = .);

     *(.bss)
     *(.bss.*)
     *(.gnu.linkonce.b.*)
     *(.sbss)
     *(.sbss.*)
     *(.gnu.linkonce.sb.*)
     *(.scommon)
     *(COMMON)

     PROVIDE (__bss_end = .);
  }
}